git@sv / enscript.git / blob
? search:


d8659a5fa2107687a62f2aa34c9eb7ef03b8f9bf
[enscript.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 AC_INIT([GNU Enscript],[1.6.6],[bug-enscript@gnu.org])
3 AC_PREREQ([2.61])
4 AC_CONFIG_SRCDIR([src/gsint.h])
5 AC_CONFIG_HEADERS([config.h])
6
7 AM_INIT_AUTOMAKE
8
9 AC_PROG_INSTALL
10
11 AC_PROG_CC
12
13 AC_USE_SYSTEM_EXTENSIONS
14
15 AC_C_CONST
16 AC_FUNC_ALLOCA
17
18 AC_HEADER_STDC
19 AC_CHECK_HEADERS([string.h stdlib.h unistd.h stdarg.h math.h pwd.h])
20 AC_CHECK_HEADERS([sys/types.h sys/stat.h])
21
22 dnl Check some functions.
23 AC_CHECK_FUNCS(strchr getcwd)
24 AC_REPLACE_FUNCS(strerror memmove memcpy strtoul)
25 AC_FUNC_VPRINTF
26
27 dnl -lsun is needed on IRIX-4.0 to get the user passwd entry through
28 dnl the yellow pages / NIS.
29 AC_CHECK_LIB(sun, main)
30
31 dnl Find out where the gethostname() is.
32 AC_CHECK_FUNC(gethostname, , [
33   AC_CHECK_LIB(nsl, gethostname, LIBS="$LIBS -lnsl", [
34     AC_CHECK_LIB(socket, gethostname)
35   ])
36 ])
37
38 AC_PROG_RANLIB
39 AC_PROG_YACC
40 AM_PROG_LEX
41
42 AC_ARG_ENABLE(debug,
43 [  --enable-debug         enable debugging], [
44   echo enabling debugging
45   if test -n "$GCC"; then
46     CFLAGS="$CFLAGS -Wall"
47   fi
48 ])
49
50 dnl Define the default output media.
51
52 AC_ARG_WITH(media,
53 [  --with-media(=MEDIA)   use output media Letter (MEDIA), default is A4],
54   if test "X$withval" != "Xno"; then
55     if test "X$withval" = "Xyes"; then
56       ac_cv_value_media='Letter'
57     else
58       ac_cv_value_media=$withval
59     fi
60   else
61     ac_cv_value_media=${MEDIA-A4}
62   fi,
63   ac_cv_value_media=${MEDIA-A4}
64 )
65 MEDIA=$ac_cv_value_media
66 AC_SUBST(MEDIA)
67
68 dnl Find the printer spooler command.
69
70 AC_CHECK_PROG(SPOOLER, lpr, lpr)
71 AC_CHECK_PROG(SPOOLER, lp, lp)
72
73 dnl user can overwrite this
74 AC_ARG_WITH(spooler,
75 [  --with-spooler=SPOOLER  set the printer spooler command],
76   if test "X$withval" != "Xno"; then
77     SPOOLER=$withval
78   fi
79 )
80
81 dnl If SPOOLER is still empty, set it to `lpr'.  After this, we should
82 dnl be able to compile enscript on HURD.
83 if test "X$SPOOLER" = "X"; then
84   SPOOLER=lpr
85 fi
86
87 dnl The PostScript language level.
88 PSLEVEL="2"
89 AC_ARG_WITH(ps-level,
90 [  --with-ps-level=LEVEL   set the PostScript language level to LEVEL],
91   if test "X$withval" != "Xno"; then
92     PSLEVEL=$withval
93   fi
94 )
95 AC_SUBST(PSLEVEL)
96
97 dnl Internationalization.
98 AM_GNU_GETTEXT
99 AM_GNU_GETTEXT_VERSION([0.17])
100
101 dnl Path separator character.
102 AC_DEFINE_UNQUOTED([PATH_SEPARATOR], [':'],
103   [Character used to separate path components.])
104 AC_DEFINE_UNQUOTED([PATH_SEPARATOR_STR], [":"],
105   [Character used to separate path components, as string.])
106
107 dnl
108 dnl Scripts
109 dnl
110
111 dnl diffpp
112
113 AC_PATH_PROG(PERL, perl)
114
115 dnl substitutions
116
117 AC_SUBST(CFLAGS)
118 AC_SUBST(LDFLAGS)
119
120 AC_CONFIG_FILES([Makefile  po/Makefile.in intl/Makefile po/Makefile \
121         compat/Makefile \
122         afm/Makefile \
123         afmlib/Makefile \
124         src/Makefile \
125         src/tests/Makefile \
126         lib/Makefile \
127         scripts/Makefile \
128         states/Makefile \
129         states/hl/Makefile \
130         states/tests/Makefile \
131         docs/Makefile \
132         w32/Makefile])
133
134 AC_OUTPUT
135
136 echo ""
137
138 echo "Enscript is now configured to your system with the following"
139 echo "user-definable options.  Please, check that they are correct and"
140 echo "match to your system's properties."
141 echo ""
142 echo "Option     Change with configure's option   Current value"
143 echo "---------------------------------------------------------"
144 echo "Media      --with-media=MEDIA               $MEDIA"
145 echo "Spooler    --with-spooler=SPOOLER           $SPOOLER"
146 echo "PS level   --with-ps-level=LEVEL            $PSLEVEL"
147 echo ""
enscript